iEat/web/WEB-INF/xsl/choose-system-to-convert-recipe.xsl

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
	xmlns:eat="http://msqr.us/xsd/ieat"
	xmlns:xweb="http://msqr.us/xsd/jaxb-web"
	exclude-result-prefixes="eat xweb">
	
    <!-- imports -->
	<xsl:import href="tmpl/default-layout.xsl"/>
	
	<!-- layout variables -->
	<xsl:variable name="layout.global.nav.page" select="''"/>
	
	<!-- helper vars -->
	<xsl:variable name="recipe" select="$aux/eat:ui/eat:recipe"/>

	<xsl:template match="xweb:x-data" mode="page-title">
		<xsl:value-of select="key('i18n','choose-system-to-convert-recipe.title')"/>
	</xsl:template>
	
	<xsl:template match="xweb:x-data" mode="page-body">
		hello
		<div class="intro">
			<xsl:value-of select="key('i18n','choose-system-to-convert-recipe.intro')" 
				disable-output-escaping="yes"/>
		</div>
		
		<div class="formLabel">
			<xsl:value-of select="key('i18n','recipe.displayName')"/>
			<xsl:text>: </xsl:text>
		</div>
		
		<div class="read-only">
			<xsl:value-of select="$recipe/eat:name"/>
		</div>
		
		<br clear="left" />
	
		<form method="post" action="{$web-context}{$ctx/xweb:path}">
			<table class="form">
				<tr>
					<th>
						<xsl:value-of select="key('i18n','recipe.system.displayName')"/>
					</th>
					<td>
						<select name="systemId">
							<xsl:apply-templates select="$aux/*/eat:system[@systemId != $recipe/eat:system/@systemId]"/>
						</select>
					</td>
				</tr>
				<tr>
					<th/>
					<td>
						<input type="submit" value="{key('i18n','continue.displayName')}"/>
						<xsl:text> </xsl:text>
						<input type="submit" name="_cancel" value="{key('i18n','cancel.displayName')}"/>
					</td>
				</tr>
			</table>
			<input type="hidden" name="recipeId" value="{$recipe/@recipeId}"/>
			<!-- handle contextual navigation -->
			<xsl:apply-templates select="$aux/eat:ui/eat:search-results" 
				mode="contextual-navigation"/>
		</form>                
	</xsl:template>

	<xsl:template match="eat:system">
	    	<option value="{@systemId}">
	    		<xsl:value-of select="."/>
	    	</option>
	</xsl:template>

</xsl:stylesheet>