iEat/web/WEB-INF/xsl/change-password.xsl

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
	xmlns:eat="http://msqr.us/xsd/ieat" 
	xmlns:xweb="http://msqr.us/xsd/jaxb-web"
	exclude-result-prefixes="eat xweb">

	<!-- imports -->
	<xsl:import href="tmpl/default-layout.xsl"/>
	
	<!-- layout variables -->
	<xsl:variable name="layout.global.nav.page" select="'change-password'"/>
	
	<!-- helper vars -->
	<xsl:variable name="user" select="xweb:x-data/xweb:x-model/eat:edit/eat:user"/>

	<xsl:template match="xweb:x-data" mode="page-title">
		<xsl:value-of select="key('i18n','change-password.title')"/>
	</xsl:template>
	
	<xsl:template match="xweb:x-data" mode="page-body">
		<div class="intro">
			<xsl:value-of select="key('i18n','change-password.intro')"
				disable-output-escaping="yes"/>
		</div>
		<form method="post" action="{$web-context}{$ctx/xweb:path}">
			<xsl:variable name="login">
				<xsl:choose>
					<xsl:when test="$user">
						<xsl:value-of select="$user/@login"/>
					</xsl:when>
					<xsl:otherwise>
						<xsl:value-of select="$req[@key='login']"/>
					</xsl:otherwise>
				</xsl:choose>
			</xsl:variable>
			<table class="form">
				<xsl:if test="string-length($login) &gt; 0">
					<tr>
						<th>
							<xsl:value-of select="key('i18n','login.displayName')"/>
						</th>
						<td>
							<xsl:value-of select="$login"/>
						</td>
					</tr>
				</xsl:if>
				<tr>
					<th>
						<xsl:value-of select="key('i18n','password.displayName')"/>
					</th>
					<td colspan="3">
						<input type="password" name="password" maxlength="64"/>
					</td>
				</tr>
				<tr>
					<th/>
					<td>
						<input type="submit" value="{key('i18n','save.displayName')}"/>
					</td>
				</tr>
			</table>
		</form>
		<script type="text/javascript" xml:space="preserve">
			<xsl:comment>
			document.forms[0].elements['password'].focus();
			//</xsl:comment>
		</script>
	</xsl:template>
	
</xsl:stylesheet>